T19 · AMM 从数学到代码

// 池子里有 reserveIn 和 reserveOut，用户投入 amountIn
uint256 k = reserveIn * reserveOut;
uint256 newReserveIn = reserveIn + amountIn;
uint256 amountOut = reserveOut - k / newReserveIn;

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

/// 0.3% 手续费，写在输入侧，留在池子里
function getAmountOut(
    uint256 amountIn,
    uint256 reserveIn,
    uint256 reserveOut
) pure returns (uint256 amountOut) {
    require(amountIn > 0, "ZERO_INPUT");
    require(reserveIn > 0 && reserveOut > 0, "NO_LIQUIDITY");

    uint256 amountInWithFee = amountIn * 997;
    uint256 numerator = amountInWithFee * reserveOut;
    uint256 denominator = reserveIn * 1000 + amountInWithFee;

    amountOut = numerator / denominator;   // 向下取整，余数留给池子
}

function swap(uint256 amount0Out, uint256 amount1Out, address to) external {
    require(amount0Out > 0 || amount1Out > 0, "ZERO_OUTPUT");
    require(amount0Out < reserve0 && amount1Out < reserve1, "NOT_ENOUGH");

    if (amount0Out > 0) _safeTransfer(token0, to, amount0Out);
    if (amount1Out > 0) _safeTransfer(token1, to, amount1Out);

    uint256 balance0 = IERC20(token0).balanceOf(address(this));
    uint256 balance1 = IERC20(token1).balanceOf(address(this));

    // 实际收到了多少：用真实余额倒推，而不是相信调用方传的参数
    uint256 amount0In = balance0 > reserve0 - amount0Out ? balance0 - (reserve0 - amount0Out) : 0;
    uint256 amount1In = balance1 > reserve1 - amount1Out ? balance1 - (reserve1 - amount1Out) : 0;
    require(amount0In > 0 || amount1In > 0, "NO_INPUT");

    // 把 0.3% 扣掉之后，乘积不允许变小
    uint256 adjusted0 = balance0 * 1000 - amount0In * 3;
    uint256 adjusted1 = balance1 * 1000 - amount1In * 3;
    require(adjusted0 * adjusted1 >= reserve0 * reserve1 * 1000 * 1000, "K");

    reserve0 = balance0;
    reserve1 = balance1;
}

function _sharesFor(uint256 amount0, uint256 amount1) internal view returns (uint256) {
    if (totalShares == 0) {
        // 第一笔：份额定义为两边数量乘积的平方根
        return _sqrt(amount0 * amount1) - MINIMUM_LIQUIDITY;
    }
    uint256 s0 = (amount0 * totalShares) / reserve0;
    uint256 s1 = (amount1 * totalShares) / reserve1;
    return s0 < s1 ? s0 : s1;   // 取小的那个：多投的部分等于捐给池子
}